mirror of
https://github.com/AuxXxilium/linux_dsm_epyc7002.git
synced 2024-11-30 13:56:53 +07:00
b75bb2365d
The icache invalidate functions should disable the icache on AM33 and wait for it to quiesce before attempting to invalidate it, and should then wait for it to quiesce again before reenabling it, but on AM34 they should invalidate directly. The same goes for the dcache invalidation, but this isn't used much. Whilst we're at it, this can be wrapped in assembler macros to remove duplicate code. The AM33 manual states that: An operation that invalidates the cache, switches the writing mode, or changes the way mode must be performed after disabling the cache, checking the busy bit, and confirming that the cache is not in operation. for the dcache [sec 2.8.3.2.1]. This is not stated so for the icache [sec 2.8.3.1.1] but the example code there suggests that it is. Whilst the AM34 manual states that the cache must be disabled for both the icache [sec 1.8.3.2.1] and the dcache [sec 1.8.3.2.1], the Panasonic hardware engineers say the manual is wrong and that disabling the caches for invalidation is wrong. Furthermore, they say that disabling the caches on the AM34 whilst running an SMP kernel can lead to incoherency between the various CPU caches and should thus be avoided. Signed-off-by: David Howells <dhowells@redhat.com>
134 lines
2.6 KiB
PHP
134 lines
2.6 KiB
PHP
/* MN10300 CPU core caching macros -*- asm -*-
|
|
*
|
|
* Copyright (C) 2007 Red Hat, Inc. All Rights Reserved.
|
|
* Written by David Howells (dhowells@redhat.com)
|
|
*
|
|
* This program is free software; you can redistribute it and/or
|
|
* modify it under the terms of the GNU General Public Licence
|
|
* as published by the Free Software Foundation; either version
|
|
* 2 of the Licence, or (at your option) any later version.
|
|
*/
|
|
|
|
|
|
###############################################################################
|
|
#
|
|
# Invalidate the instruction cache.
|
|
# A0: Should hold CHCTR
|
|
# D0: Should have been read from CHCTR
|
|
# D1: Will be clobbered
|
|
#
|
|
# On some cores it is necessary to disable the icache whilst we do this.
|
|
#
|
|
###############################################################################
|
|
.macro invalidate_icache,disable_irq
|
|
|
|
#if defined(CONFIG_AM33_2) || defined(CONFIG_AM33_3)
|
|
.if \disable_irq
|
|
# don't want an interrupt routine seeing a disabled cache
|
|
mov epsw,d1
|
|
and ~EPSW_IE,epsw
|
|
or EPSW_NMID,epsw
|
|
nop
|
|
nop
|
|
.endif
|
|
|
|
# disable the icache
|
|
and ~CHCTR_ICEN,d0
|
|
movhu d0,(a0)
|
|
|
|
# and wait for it to calm down
|
|
setlb
|
|
movhu (a0),d0
|
|
btst CHCTR_ICBUSY,d0
|
|
lne
|
|
|
|
# invalidate
|
|
or CHCTR_ICINV,d0
|
|
movhu d0,(a0)
|
|
|
|
# wait for the cache to finish
|
|
setlb
|
|
movhu (a0),d0
|
|
btst CHCTR_ICBUSY,d0
|
|
lne
|
|
|
|
# and reenable it
|
|
or CHCTR_ICEN,d0
|
|
movhu d0,(a0)
|
|
movhu (a0),d0
|
|
|
|
.if \disable_irq
|
|
LOCAL_IRQ_RESTORE(d1)
|
|
.endif
|
|
|
|
#else /* CONFIG_AM33_2 || CONFIG_AM33_3 */
|
|
|
|
# invalidate
|
|
or CHCTR_ICINV,d0
|
|
movhu d0,(a0)
|
|
movhu (a0),d0
|
|
|
|
#endif /* CONFIG_AM33_2 || CONFIG_AM33_3 */
|
|
.endm
|
|
|
|
###############################################################################
|
|
#
|
|
# Invalidate the data cache.
|
|
# A0: Should hold CHCTR
|
|
# D0: Should have been read from CHCTR
|
|
# D1: Will be clobbered
|
|
#
|
|
# On some cores it is necessary to disable the dcache whilst we do this.
|
|
#
|
|
###############################################################################
|
|
.macro invalidate_dcache,disable_irq
|
|
|
|
#if defined(CONFIG_AM33_2) || defined(CONFIG_AM33_3)
|
|
.if \disable_irq
|
|
# don't want an interrupt routine seeing a disabled cache
|
|
mov epsw,d1
|
|
and ~EPSW_IE,epsw
|
|
or EPSW_NMID,epsw
|
|
nop
|
|
nop
|
|
.endif
|
|
|
|
# disable the dcache
|
|
and ~CHCTR_DCEN,d0
|
|
movhu d0,(a0)
|
|
|
|
# and wait for it to calm down
|
|
setlb
|
|
movhu (a0),d0
|
|
btst CHCTR_DCBUSY,d0
|
|
lne
|
|
|
|
# invalidate
|
|
or CHCTR_DCINV,d0
|
|
movhu d0,(a0)
|
|
|
|
# wait for the cache to finish
|
|
setlb
|
|
movhu (a0),d0
|
|
btst CHCTR_DCBUSY,d0
|
|
lne
|
|
|
|
# and reenable it
|
|
or CHCTR_DCEN,d0
|
|
movhu d0,(a0)
|
|
movhu (a0),d0
|
|
|
|
.if \disable_irq
|
|
LOCAL_IRQ_RESTORE(d1)
|
|
.endif
|
|
|
|
#else /* CONFIG_AM33_2 || CONFIG_AM33_3 */
|
|
|
|
# invalidate
|
|
or CHCTR_DCINV,d0
|
|
movhu d0,(a0)
|
|
movhu (a0),d0
|
|
|
|
#endif /* CONFIG_AM33_2 || CONFIG_AM33_3 */
|
|
.endm
|