mirror of
https://github.com/AuxXxilium/linux_dsm_epyc7002.git
synced 2024-11-27 06:41:11 +07:00
6ebbf2ce43
ARMv6 and greater introduced a new instruction ("bx") which can be used
to return from function calls. Recent CPUs perform better when the
"bx lr" instruction is used rather than the "mov pc, lr" instruction,
and this sequence is strongly recommended to be used by the ARM
architecture manual (section A.4.1.1).
We provide a new macro "ret" with all its variants for the condition
code which will resolve to the appropriate instruction.
Rather than doing this piecemeal, and miss some instances, change all
the "mov pc" instances to use the new macro, with the exception of
the "movs" instruction and the kprobes code. This allows us to detect
the "mov pc, lr" case and fix it up - and also gives us the possibility
of deploying this for other registers depending on the CPU selection.
Reported-by: Will Deacon <will.deacon@arm.com>
Tested-by: Stephen Warren <swarren@nvidia.com> # Tegra Jetson TK1
Tested-by: Robert Jarzmik <robert.jarzmik@free.fr> # mioa701_bootresume.S
Tested-by: Andrew Lunn <andrew@lunn.ch> # Kirkwood
Tested-by: Shawn Guo <shawn.guo@freescale.com>
Tested-by: Tony Lindgren <tony@atomide.com> # OMAPs
Tested-by: Gregory CLEMENT <gregory.clement@free-electrons.com> # Armada XP, 375, 385
Acked-by: Sekhar Nori <nsekhar@ti.com> # DaVinci
Acked-by: Christoffer Dall <christoffer.dall@linaro.org> # kvm/hyp
Acked-by: Haojian Zhuang <haojian.zhuang@gmail.com> # PXA3xx
Acked-by: Stefano Stabellini <stefano.stabellini@eu.citrix.com> # Xen
Tested-by: Uwe Kleine-König <u.kleine-koenig@pengutronix.de> # ARMv7M
Tested-by: Simon Horman <horms+renesas@verge.net.au> # Shmobile
Signed-off-by: Russell King <rmk+kernel@arm.linux.org.uk>
99 lines
2.2 KiB
ArmAsm
99 lines
2.2 KiB
ArmAsm
/*
|
|
* linux/arch/arm/lib/putuser.S
|
|
*
|
|
* Copyright (C) 2001 Russell King
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
* Idea from x86 version, (C) Copyright 1998 Linus Torvalds
|
|
*
|
|
* These functions have a non-standard call interface to make
|
|
* them more efficient, especially as they return an error
|
|
* value in addition to the "real" return value.
|
|
*
|
|
* __put_user_X
|
|
*
|
|
* Inputs: r0 contains the address
|
|
* r1 contains the address limit, which must be preserved
|
|
* r2, r3 contains the value
|
|
* Outputs: r0 is the error code
|
|
* lr corrupted
|
|
*
|
|
* No other registers must be altered. (see <asm/uaccess.h>
|
|
* for specific ASM register usage).
|
|
*
|
|
* Note that ADDR_LIMIT is either 0 or 0xc0000000
|
|
* Note also that it is intended that __put_user_bad is not global.
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
#include <asm/errno.h>
|
|
#include <asm/domain.h>
|
|
|
|
ENTRY(__put_user_1)
|
|
check_uaccess r0, 1, r1, ip, __put_user_bad
|
|
1: TUSER(strb) r2, [r0]
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__put_user_1)
|
|
|
|
ENTRY(__put_user_2)
|
|
check_uaccess r0, 2, r1, ip, __put_user_bad
|
|
mov ip, r2, lsr #8
|
|
#ifdef CONFIG_THUMB2_KERNEL
|
|
#ifndef __ARMEB__
|
|
2: TUSER(strb) r2, [r0]
|
|
3: TUSER(strb) ip, [r0, #1]
|
|
#else
|
|
2: TUSER(strb) ip, [r0]
|
|
3: TUSER(strb) r2, [r0, #1]
|
|
#endif
|
|
#else /* !CONFIG_THUMB2_KERNEL */
|
|
#ifndef __ARMEB__
|
|
2: TUSER(strb) r2, [r0], #1
|
|
3: TUSER(strb) ip, [r0]
|
|
#else
|
|
2: TUSER(strb) ip, [r0], #1
|
|
3: TUSER(strb) r2, [r0]
|
|
#endif
|
|
#endif /* CONFIG_THUMB2_KERNEL */
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__put_user_2)
|
|
|
|
ENTRY(__put_user_4)
|
|
check_uaccess r0, 4, r1, ip, __put_user_bad
|
|
4: TUSER(str) r2, [r0]
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__put_user_4)
|
|
|
|
ENTRY(__put_user_8)
|
|
check_uaccess r0, 8, r1, ip, __put_user_bad
|
|
#ifdef CONFIG_THUMB2_KERNEL
|
|
5: TUSER(str) r2, [r0]
|
|
6: TUSER(str) r3, [r0, #4]
|
|
#else
|
|
5: TUSER(str) r2, [r0], #4
|
|
6: TUSER(str) r3, [r0]
|
|
#endif
|
|
mov r0, #0
|
|
ret lr
|
|
ENDPROC(__put_user_8)
|
|
|
|
__put_user_bad:
|
|
mov r0, #-EFAULT
|
|
ret lr
|
|
ENDPROC(__put_user_bad)
|
|
|
|
.pushsection __ex_table, "a"
|
|
.long 1b, __put_user_bad
|
|
.long 2b, __put_user_bad
|
|
.long 3b, __put_user_bad
|
|
.long 4b, __put_user_bad
|
|
.long 5b, __put_user_bad
|
|
.long 6b, __put_user_bad
|
|
.popsection
|