mirror of
https://github.com/AuxXxilium/linux_dsm_epyc7002.git
synced 2024-11-30 13:46:47 +07:00
6ebbf2ce43
ARMv6 and greater introduced a new instruction ("bx") which can be used
to return from function calls. Recent CPUs perform better when the
"bx lr" instruction is used rather than the "mov pc, lr" instruction,
and this sequence is strongly recommended to be used by the ARM
architecture manual (section A.4.1.1).
We provide a new macro "ret" with all its variants for the condition
code which will resolve to the appropriate instruction.
Rather than doing this piecemeal, and miss some instances, change all
the "mov pc" instances to use the new macro, with the exception of
the "movs" instruction and the kprobes code. This allows us to detect
the "mov pc, lr" case and fix it up - and also gives us the possibility
of deploying this for other registers depending on the CPU selection.
Reported-by: Will Deacon <will.deacon@arm.com>
Tested-by: Stephen Warren <swarren@nvidia.com> # Tegra Jetson TK1
Tested-by: Robert Jarzmik <robert.jarzmik@free.fr> # mioa701_bootresume.S
Tested-by: Andrew Lunn <andrew@lunn.ch> # Kirkwood
Tested-by: Shawn Guo <shawn.guo@freescale.com>
Tested-by: Tony Lindgren <tony@atomide.com> # OMAPs
Tested-by: Gregory CLEMENT <gregory.clement@free-electrons.com> # Armada XP, 375, 385
Acked-by: Sekhar Nori <nsekhar@ti.com> # DaVinci
Acked-by: Christoffer Dall <christoffer.dall@linaro.org> # kvm/hyp
Acked-by: Haojian Zhuang <haojian.zhuang@gmail.com> # PXA3xx
Acked-by: Stefano Stabellini <stefano.stabellini@eu.citrix.com> # Xen
Tested-by: Uwe Kleine-König <u.kleine-koenig@pengutronix.de> # ARMv7M
Tested-by: Simon Horman <horms+renesas@verge.net.au> # Shmobile
Signed-off-by: Russell King <rmk+kernel@arm.linux.org.uk>
197 lines
4.8 KiB
ArmAsm
197 lines
4.8 KiB
ArmAsm
/*
|
|
* linux/arch/arm/lib/findbit.S
|
|
*
|
|
* Copyright (C) 1995-2000 Russell King
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License version 2 as
|
|
* published by the Free Software Foundation.
|
|
*
|
|
* 16th March 2001 - John Ripley <jripley@sonicblue.com>
|
|
* Fixed so that "size" is an exclusive not an inclusive quantity.
|
|
* All users of these functions expect exclusive sizes, and may
|
|
* also call with zero size.
|
|
* Reworked by rmk.
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
.text
|
|
|
|
/*
|
|
* Purpose : Find a 'zero' bit
|
|
* Prototype: int find_first_zero_bit(void *addr, unsigned int maxbit);
|
|
*/
|
|
ENTRY(_find_first_zero_bit_le)
|
|
teq r1, #0
|
|
beq 3f
|
|
mov r2, #0
|
|
1:
|
|
ARM( ldrb r3, [r0, r2, lsr #3] )
|
|
THUMB( lsr r3, r2, #3 )
|
|
THUMB( ldrb r3, [r0, r3] )
|
|
eors r3, r3, #0xff @ invert bits
|
|
bne .L_found @ any now set - found zero bit
|
|
add r2, r2, #8 @ next bit pointer
|
|
2: cmp r2, r1 @ any more?
|
|
blo 1b
|
|
3: mov r0, r1 @ no free bits
|
|
ret lr
|
|
ENDPROC(_find_first_zero_bit_le)
|
|
|
|
/*
|
|
* Purpose : Find next 'zero' bit
|
|
* Prototype: int find_next_zero_bit(void *addr, unsigned int maxbit, int offset)
|
|
*/
|
|
ENTRY(_find_next_zero_bit_le)
|
|
teq r1, #0
|
|
beq 3b
|
|
ands ip, r2, #7
|
|
beq 1b @ If new byte, goto old routine
|
|
ARM( ldrb r3, [r0, r2, lsr #3] )
|
|
THUMB( lsr r3, r2, #3 )
|
|
THUMB( ldrb r3, [r0, r3] )
|
|
eor r3, r3, #0xff @ now looking for a 1 bit
|
|
movs r3, r3, lsr ip @ shift off unused bits
|
|
bne .L_found
|
|
orr r2, r2, #7 @ if zero, then no bits here
|
|
add r2, r2, #1 @ align bit pointer
|
|
b 2b @ loop for next bit
|
|
ENDPROC(_find_next_zero_bit_le)
|
|
|
|
/*
|
|
* Purpose : Find a 'one' bit
|
|
* Prototype: int find_first_bit(const unsigned long *addr, unsigned int maxbit);
|
|
*/
|
|
ENTRY(_find_first_bit_le)
|
|
teq r1, #0
|
|
beq 3f
|
|
mov r2, #0
|
|
1:
|
|
ARM( ldrb r3, [r0, r2, lsr #3] )
|
|
THUMB( lsr r3, r2, #3 )
|
|
THUMB( ldrb r3, [r0, r3] )
|
|
movs r3, r3
|
|
bne .L_found @ any now set - found zero bit
|
|
add r2, r2, #8 @ next bit pointer
|
|
2: cmp r2, r1 @ any more?
|
|
blo 1b
|
|
3: mov r0, r1 @ no free bits
|
|
ret lr
|
|
ENDPROC(_find_first_bit_le)
|
|
|
|
/*
|
|
* Purpose : Find next 'one' bit
|
|
* Prototype: int find_next_zero_bit(void *addr, unsigned int maxbit, int offset)
|
|
*/
|
|
ENTRY(_find_next_bit_le)
|
|
teq r1, #0
|
|
beq 3b
|
|
ands ip, r2, #7
|
|
beq 1b @ If new byte, goto old routine
|
|
ARM( ldrb r3, [r0, r2, lsr #3] )
|
|
THUMB( lsr r3, r2, #3 )
|
|
THUMB( ldrb r3, [r0, r3] )
|
|
movs r3, r3, lsr ip @ shift off unused bits
|
|
bne .L_found
|
|
orr r2, r2, #7 @ if zero, then no bits here
|
|
add r2, r2, #1 @ align bit pointer
|
|
b 2b @ loop for next bit
|
|
ENDPROC(_find_next_bit_le)
|
|
|
|
#ifdef __ARMEB__
|
|
|
|
ENTRY(_find_first_zero_bit_be)
|
|
teq r1, #0
|
|
beq 3f
|
|
mov r2, #0
|
|
1: eor r3, r2, #0x18 @ big endian byte ordering
|
|
ARM( ldrb r3, [r0, r3, lsr #3] )
|
|
THUMB( lsr r3, #3 )
|
|
THUMB( ldrb r3, [r0, r3] )
|
|
eors r3, r3, #0xff @ invert bits
|
|
bne .L_found @ any now set - found zero bit
|
|
add r2, r2, #8 @ next bit pointer
|
|
2: cmp r2, r1 @ any more?
|
|
blo 1b
|
|
3: mov r0, r1 @ no free bits
|
|
ret lr
|
|
ENDPROC(_find_first_zero_bit_be)
|
|
|
|
ENTRY(_find_next_zero_bit_be)
|
|
teq r1, #0
|
|
beq 3b
|
|
ands ip, r2, #7
|
|
beq 1b @ If new byte, goto old routine
|
|
eor r3, r2, #0x18 @ big endian byte ordering
|
|
ARM( ldrb r3, [r0, r3, lsr #3] )
|
|
THUMB( lsr r3, #3 )
|
|
THUMB( ldrb r3, [r0, r3] )
|
|
eor r3, r3, #0xff @ now looking for a 1 bit
|
|
movs r3, r3, lsr ip @ shift off unused bits
|
|
bne .L_found
|
|
orr r2, r2, #7 @ if zero, then no bits here
|
|
add r2, r2, #1 @ align bit pointer
|
|
b 2b @ loop for next bit
|
|
ENDPROC(_find_next_zero_bit_be)
|
|
|
|
ENTRY(_find_first_bit_be)
|
|
teq r1, #0
|
|
beq 3f
|
|
mov r2, #0
|
|
1: eor r3, r2, #0x18 @ big endian byte ordering
|
|
ARM( ldrb r3, [r0, r3, lsr #3] )
|
|
THUMB( lsr r3, #3 )
|
|
THUMB( ldrb r3, [r0, r3] )
|
|
movs r3, r3
|
|
bne .L_found @ any now set - found zero bit
|
|
add r2, r2, #8 @ next bit pointer
|
|
2: cmp r2, r1 @ any more?
|
|
blo 1b
|
|
3: mov r0, r1 @ no free bits
|
|
ret lr
|
|
ENDPROC(_find_first_bit_be)
|
|
|
|
ENTRY(_find_next_bit_be)
|
|
teq r1, #0
|
|
beq 3b
|
|
ands ip, r2, #7
|
|
beq 1b @ If new byte, goto old routine
|
|
eor r3, r2, #0x18 @ big endian byte ordering
|
|
ARM( ldrb r3, [r0, r3, lsr #3] )
|
|
THUMB( lsr r3, #3 )
|
|
THUMB( ldrb r3, [r0, r3] )
|
|
movs r3, r3, lsr ip @ shift off unused bits
|
|
bne .L_found
|
|
orr r2, r2, #7 @ if zero, then no bits here
|
|
add r2, r2, #1 @ align bit pointer
|
|
b 2b @ loop for next bit
|
|
ENDPROC(_find_next_bit_be)
|
|
|
|
#endif
|
|
|
|
/*
|
|
* One or more bits in the LSB of r3 are assumed to be set.
|
|
*/
|
|
.L_found:
|
|
#if __LINUX_ARM_ARCH__ >= 5
|
|
rsb r0, r3, #0
|
|
and r3, r3, r0
|
|
clz r3, r3
|
|
rsb r3, r3, #31
|
|
add r0, r2, r3
|
|
#else
|
|
tst r3, #0x0f
|
|
addeq r2, r2, #4
|
|
movne r3, r3, lsl #4
|
|
tst r3, #0x30
|
|
addeq r2, r2, #2
|
|
movne r3, r3, lsl #2
|
|
tst r3, #0x40
|
|
addeq r2, r2, #1
|
|
mov r0, r2
|
|
#endif
|
|
cmp r1, r0 @ Clamp to maxbit
|
|
movlo r0, r1
|
|
ret lr
|
|
|